asp利用XMLHTTP组件获取网页源文件

以下是一个将首页生成静态HTML的源码。

<%
httphost=Request.ServerVariables("HTTP_HOST")
siteid=request("siteid")
urlurl="http://"&httphost&"/index.asp?now="&Now()  'now保证每个URL都不一样
getsms=gethttppage(urlurl)
filename="index.htm"
whichfile=server.mappath(filename)
response.write whichfile
if len(getsms)>100 and not instr(getsms,"Internet 信息服务 (IIS)") then
SaveToFile getsms,whichfile
response.write "完成<a href=index.htm>返回</a>"
response.write "<a href="">首页</a>"

end if

%>
<%
 function getHTTPPage(url)
  on error resume next
  dim http
  set http=Server.createobject("Microsoft.XMLHTTP") '调用XMLhttp组件
  Http.open "GET",url,false
  Http.send()
  if Http.readystate<>4 then
   exit function
  end if
  getHTTPPage=bytes2BSTR(Http.responseBody)
  set http=nothing
  if err.number<>0 then err.Clear 
 end function

 Function bytes2BSTR(vIn)
  dim strReturn
  dim i1,ThisCharCode,NextCharCode
  strReturn = ""
  For i1 = 1 To LenB(vIn)
   ThisCharCode = AscB(MidB(vIn,i1,1))
   If ThisCharCode < &H80 Then
    strReturn = strReturn & Chr(ThisCharCode)
   Else
    NextCharCode = AscB(MidB(vIn,i1+1,1))
    strReturn = strReturn & Chr(CLng(ThisCharCode) * &H100 + CInt(NextCharCode))
    i1 = i1 + 1
   End If
  Next
  bytes2BSTR = strReturn
 End Function
        '存储内容到文件
Sub SaveToFile(ByVal strBody,ByVal File)
    Dim objStream
    On Error Resume Next
    Set objStream = Server.CreateObject("ADODB.Stream")
    If Err.Number=-2147221005 Then
        Response.Write "<div align='center'>非常遗憾,您的主机不支持ADODB.Stream,不能使用本程序</div>"
        Err.Clear
    else
    With objStream
        .Type = 2
        .Open
        .Charset = "GB2312"
        .Position = objStream.Size
        .WriteText = strBody
        .SaveToFile File,2
        .Close
    End With
    end if
    Set objStream = Nothing
End Sub
%>